Membangun Server Web menggunakan ESP8266

Membangun Server Web menggunakan ESP8266

February 25, 2019
iotqu - Membangun Server Web menggunakan ESP8266
Tutorial ini adalah panduan langkah demi langkah yang menunjukkan kepada Anda bagaimana membangun Server Web ESP8266 secara mandiri yang mengontrol dua output (berupa dua LED). Server Web ESP8266 ini responsif dalam seluler dan dapat diakses dengan perangkat apa pun yang sebagai browser di jaringan lokal Anda.

Tutorial ini mencakup dua metode berbeda untuk membangun server web:
  • Bagian 1: Buat Server Web Menggunakan Arduino IDE
  • Bagian 2: Buat Server Web Menggunakan NodeMCU


BAGIAN 1: BUAT SERVER WEB MENGGUNAKAN ARDUINO IDE
Bagian ini menunjukkan kepada Anda cara membuat server web untuk mengontrol dua output menggunakan Arduino IDE. Anda dapat menggunakan metode ini untuk membuat server web yang berbeda untuk memenuhi kebutuhan Anda.
Mempersiapkan software Arduino IDE
  1. Unduh dan instal software Arduino IDE pada sistem operasi Anda.
  2. Kemudian, Anda perlu menginstal board ESP8266 untuk IDE Arduino. Untuk itu, buka File > Preferensi.
  3. Masukkan http://arduino.esp8266.com/stable/package_esp8266com_index.json ke dalam bidang "Additional Board Manager URLs" seperti yang ditunjukkan pada gambar di bawah ini. Kemudian, klik tombol "OK".

4. Buka Tools > Board > Boards Manager ...

5. Gulir ke bawah, pilih menu board ESP8266 dan instal "platform esp8266", seperti yang ditunjukkan pada gambar di bawah ini.

6. Buka Tools > Board dan pilih board ESP8266 Anda. Kemudian, buka kembali IDE Arduino Anda.
Kode
Salin kode di bawah ini ke IDE Arduino Anda, tetapi jangan mengunggahnya. Anda perlu membuat beberapa perubahan untuk membuatnya bekerja untuk Anda. Anda perlu memodifikasi dua variabel berikut dengan kredensial jaringan Anda, sehingga ESP8266 Anda dapat membuat koneksi dengan router Anda.

// Load Wi-Fi library
#include <ESP8266WiFi.h>
// Replace with your network credentials
const char* ssid     = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";
// Set web server port number to 80
WiFiServer server(80);
// Variable to store the HTTP request
String header;
// Auxiliar variables to store the current output state
String output5State = "off";
String output4State = "off";
// Assign output variables to GPIO pins
const int output5 = 5;
const int output4 = 4;
void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output5, OUTPUT);
  pinMode(output4, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output5, LOW);
  digitalWrite(output4, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}
void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /5/on") >= 0) {
              Serial.println("GPIO 5 on");
              output5State = "on";
              digitalWrite(output5, HIGH);
            } else if (header.indexOf("GET /5/off") >= 0) {
              Serial.println("GPIO 5 off");
              output5State = "off";
              digitalWrite(output5, LOW);
            } else if (header.indexOf("GET /4/on") >= 0) {
              Serial.println("GPIO 4 on");
              output4State = "on";
              digitalWrite(output4, HIGH);
            } else if (header.indexOf("GET /4/off") >= 0) {
              Serial.println("GPIO 4 off");
              output4State = "off";
              digitalWrite(output4, LOW);
            }
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>ESP8266 Web Server</h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 5  
            client.println("<p>GPIO 5 - State " + output5State + "</p>");
            // If the output5State is off, it displays the ON button       
            if (output5State=="off") {
              client.println("<p><a href=\"/5/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/5/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
            // Display current state, and ON/OFF buttons for GPIO 4  
            client.println("<p>GPIO 4 - State " + output4State + "</p>");
            // If the output4State is off, it displays the ON button       
            if (output4State=="off") {
              client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Mengunggah Sketsa

1. Mengunggah Sketsa ke ESP-12E
Jika Anda menggunakan Kit NodeMCU ESP-12E, mengunggah sketsa itu sangat sederhana, karena ia memiliki pemrogram bawaan. Tancapkan papan Anda ke komputer Anda. Pastikan Anda memiliki papan yang tepat dan port COM yang dipilih.
Kemudian, klik "Tombol upload" di Arduino IDE dan tunggu beberapa detik hingga Anda melihat pesan "Selesai mengunggah." Di sudut kiri bawah.


2.Mengunggah Sketsa ke ESP-01
Mengunggah kode ke ESP-01 membutuhkan komunikasi serial antara ESP8266 Anda dan Programmer FTDI seperti yang ditunjukkan pada diagram skematik di bawah ini.

Tabel berikut menunjukkan koneksi yang perlu Anda buat antara ESP8266 dan programmer FTDI.

Jika Anda memiliki Programmer FTDI yang benar-benar baru dan Anda perlu menginstal driver FTDI di PC Windows, kunjungi situs web ini untuk driver resmi . Atau, Anda dapat menghubungi 
penjual yang menjual Anda Programmer FTDI.
Kemudian, Anda hanya perlu menghubungkan programmer FTDI ke komputer Anda, dan mengunggah kodenya ke ESP8266.

Skema

Untuk membangun sirkuit Anda membutuhkan bagian-bagian berikut:
  • NodeMCU ESP8266 12-E
  • 2 x LED
  • 2 x Resistor (220 atau 330 ohm)
  • Breadboard
  • Kabel pelompat

Hubungkan dua LED ke ESP8266 Anda seperti yang ditunjukkan dalam diagram skematik berikut - dengan satu LED yang terhubung ke GPIO 4, dan satu lagi ke GPIO 5.


Jika Anda menggunakan ESP8266-01, gunakan diagram skematik berikut sebagai referensi, tetapi Anda perlu mengubah tugas GPIO dalam kode (ke GPIO 2 dan GPIO 0).

Menguji Server Web
Sekarang, Anda dapat mengunggah kodenya, dan itu akan langsung berfungsi. Jangan lupa untuk memeriksa apakah Anda memiliki papan yang tepat dan port COM yang dipilih, jika tidak Anda akan mendapatkan kesalahan ketika mencoba mengunggah. Buka Monitor Seri dengan kecepatan baud 115200.
Alamat IP ESP
Tekan tombol RESP ESP8266, dan itu akan menampilkan alamat IP ESP pada serial monitor

Salin alamat IP itu, karena Anda memerlukannya untuk mengakses server web.

Mengakses Server Web
Buka browser Anda, ketik alamat IP ESP, dan Anda akan melihat halaman berikut. Halaman ini dikirim oleh ESP8266 ketika Anda membuat permintaan pada alamat IP ESP.

Jika melihat serial monitor, Anda dapat melihat apa yang terjadi di latar belakang. ESP menerima permintaan HTTP dari klien baru - dalam hal ini, browser Anda. Anda juga dapat melihat informasi lain tentang permintaan HTTP - bidang ini disebut bidang header HTTP, dan mereka menentukan parameter operasi transaksi HTTP.

Menguji Server Web
Mari kita coba server web. Klik tombol untuk menghidupkan GPIO 5. ESP menerima permintaan pada / 5 / pada URL, dan ternyata LED 5 AKTIF.
Status LED juga diperbarui di halaman web.

Tes tombol GPIO 4 dan periksa apakah berfungsi dengan cara yang sama.

Artikel Terkait

Next
« Prev Post
Previous
Next Post »
Subscribe to: Post Comments (Atom)